8.2 - AppleScript - getting the Shipping Carrier the buyer chose?

[markus]

Did I miss something or is it still not possible to get the chose shipping service from GS with Apple Script?
I had the hope that with GS8 I do not need to use the GUI Scripting things anymore…

At the moment I get the chosen shipping service that way:

tell application “System Events”
tell process “GarageSale”
set myValue to value of static text 8 of scroll area 3 of splitter group 1 of window “GarageSale”
end tell
end tell
set the clipboard to myValue

for the chosen service

and

tell application “System Events”
tell process “GarageSale”
set myValue to value of static text 27 of scroll area 3 of splitter group 1 of window “GarageSale”
end tell
end tell
set the clipboard to myValue

for getting the shipping costs.

Not elegant but working.
Fortunately it is the same static text filed in GS8 as it was in GS7

But being able to use it with a direct AppleScript command would be nice.

[Neal]

Here is an AppleScript I use to check for my “invalid” Shipping Options…

Neal

tell application "GarageSale"
set templateServiceName to "Expedited Shipping"
set templateServiceNameFC to "Expedited Shipping" -- "USPS First Class Package"
set templateServiceNamePM to "Expedited Shipping" -- "USPS Priority Mail"
set templateList to ""
repeat with aTemplate in (get selected ebay listings) -- every ebay listing
	set theShippingOption to (the shipping option of aTemplate)
	tell theShippingOption
		if ((handling costs is not 0.0) ¬
			or (use calculated shipping is true) or (offer free calculated shipping is true) ¬
			or ((originating postal code is not missing value) and (originating postal code is not "")) ¬
			or (use international calculated shipping is true) or (international handling costs is not 0.0)) ¬
			or (major weight is not 0.0) or (minor weight is not 0.0) ¬
			or (package length is not 0.0) or (package depth is not 0.0) or (package width is not 0.0) ¬
			then
			set templateList to templateList & title of aTemplate & ": " & handling costs & ¬
				", " & use calculated shipping & ", " & offer free calculated shipping & ¬
				", " & originating postal code & ¬
				", " & use international calculated shipping & ", " & international handling costs & ¬
				", " & major weight & ", " & minor weight & ¬
				", " & package length & ", " & package depth & ", " & package width & ¬
				return
		end if
		if ((count of every ebay shipping service) is not 1) then
			set templateList to templateList & title of aTemplate & ": " & (count of every ebay shipping service) & return
		end if
		repeat with theShippingService in every ebay shipping service
			tell theShippingService
				-- set templateList to templateList & title of aTemplate & ": " & service name & return
				if (((service name is not templateServiceName) and (service name is not templateServiceNameFC) and (service name is not templateServiceNamePM)) ¬
					or (is international is true) or (fee amount is not 0.0) or (use additional fee is true) or (additional fee amount is not 0.0) or (use surcharge fee is true) or (surcharge fee amount is not 0.0)) then
					set templateList to templateList & title of aTemplate & ": " & service name & ", " & is international & ", " & fee amount & ", " & use additional fee & ", " & additional fee amount & ", " & use surcharge fee & ", " & surcharge fee amount & return
				end if
			end tell
		end repeat
	end tell
end repeat
end tell
display dialog "The listings with shipping options are:" default answer templateList

[markus]

Hi Neal! Thanks for your answer. Thats a hell of a script for a simple task

[Neal]

It is just an example. It checks lots of values.

Just cut/copy and take the pieces you want.

Neal

[markus]

Thanks. I just had the hope that I missed something simple like “set myValue to chosen shipment of ebay order” or like that…

Feature request: Ability to get the the chosen shipping service and shipping fee (the fee would not be necessary…) with Apple Script!